PROGRAM nag_sparse_prec_ex01

      ! Example Program Text for nag_sparse_prec
      ! NAG fl90, Release 4. NAG Copyright 2000.

      ! .. Use Statements ..
      USE nag_examples_io, ONLY : nag_std_in, nag_std_out
      USE nag_sparse_mat, ONLY : nag_sparse_mat_init_csc, &
       nag_sparse_mat_real_wp => nag_sparse_mat_real_dp, nag_deallocate
      USE nag_sparse_prec, ONLY : nag_sparse_prec_init_jac
      USE nag_sparse_lin_sys, ONLY : nag_sparse_gen_lin_sol
      ! .. Implicit None Statement ..
      IMPLICIT NONE
      ! .. Intrinsic Functions ..
      INTRINSIC KIND
      ! .. Parameters ..
      INTEGER, PARAMETER :: wp = KIND(1.0D0)
      ! .. Local Scalars ..
      INTEGER :: i, n, nnz
      TYPE (nag_sparse_mat_real_wp) :: a, c_jac
      ! .. Local Arrays ..
      INTEGER, ALLOCATABLE :: col_ptr(:), row(:)
      REAL (wp), ALLOCATABLE :: b(:), value(:), x(:)
      ! .. Executable Statements ..
      WRITE (nag_std_out,*) 'Example Program Results for nag_sparse_prec_ex01'

      READ (nag_std_in,*)          ! Skip heading in data file
      READ (nag_std_in,*) n, nnz

      ALLOCATE (row(nnz),col_ptr(n),value(nnz),b(n),x(n))

      DO i = 1, nnz
        READ (nag_std_in,*) value(i), row(i)
      END DO
      READ (nag_std_in,*) col_ptr
      READ (nag_std_in,*) b

      x = 0.0_wp

      CALL nag_sparse_mat_init_csc(a,value,row,col_ptr)

      CALL nag_sparse_prec_init_jac(a,c_jac)

      WRITE (nag_std_out,*)
      WRITE (nag_std_out,*) 'Method: TFQMR with Jacobi preconditioner'
      WRITE (nag_std_out,*)

      CALL nag_sparse_gen_lin_sol(a,b,x,method='t',p=c_jac)

      ! Output results

      WRITE (nag_std_out,*) ' Solution'
      WRITE (nag_std_out,'(10F7.1)') x

      CALL nag_deallocate(a)
      CALL nag_deallocate(c_jac)
      DEALLOCATE (row,col_ptr,value,b,x)

    END PROGRAM nag_sparse_prec_ex01