PROGRAM nag_sparse_prec_ex03

      ! Example Program Text for nag_sparse_prec
      ! NAG fl90, Release 4. NAG Copyright 2000.

      ! .. Use Statements ..
      USE nag_examples_io, ONLY : nag_std_in, nag_std_out
      USE nag_sparse_mat, ONLY : nag_sparse_mat_init_coo, &
       nag_sparse_mat_real_wp => nag_sparse_mat_real_dp, nag_deallocate
      USE nag_sparse_prec, ONLY : nag_sparse_prec_init_ilu, &
       nag_sparse_prec_sol
      ! .. Implicit None Statement ..
      IMPLICIT NONE
      ! .. Intrinsic Functions ..
      INTRINSIC KIND
      ! .. Parameters ..
      INTEGER, PARAMETER :: wp = KIND(1.0D0)
      ! .. Local Scalars ..
      INTEGER :: i, n, nnz, num_pivot
      REAL (wp) :: drop_tol
      TYPE (nag_sparse_mat_real_wp) :: a, c_ilu
      ! .. Local Arrays ..
      INTEGER, ALLOCATABLE :: col(:), row(:)
      REAL (wp), ALLOCATABLE :: r(:), value(:), z(:)
      ! .. Executable Statements ..
      WRITE (nag_std_out,*) 'Example Program Results for nag_sparse_prec_ex03'

      READ (nag_std_in,*)          ! Skip heading in data file
      READ (nag_std_in,*) n, nnz

      ALLOCATE (row(nnz),col(nnz),value(nnz),r(n),z(n))

      DO i = 1, nnz
        READ (nag_std_in,*) value(i), row(i), col(i)
      END DO
      READ (nag_std_in,*) r

      CALL nag_sparse_mat_init_coo(a,n,value,row,col)

      drop_tol = 0.0_wp
      CALL nag_sparse_prec_init_ilu(a,c_ilu,drop_tol=drop_tol, &
       num_pivot=num_pivot)

      IF (num_pivot>0) THEN
        WRITE (nag_std_out,*) 'Factorization is not complete'
      ELSE

        CALL nag_sparse_prec_sol(c_ilu,r,z)

        ! Output results

        WRITE (nag_std_out,*)
        WRITE (nag_std_out,*) 'Solution of linear system'
        WRITE (nag_std_out,'(10F7.1)') z

      END IF

      CALL nag_deallocate(a)
      CALL nag_deallocate(c_ilu)
      DEALLOCATE (row,col,value,r,z)

    END PROGRAM nag_sparse_prec_ex03