PROGRAM nag_sym_eig_ex03

      ! Example Program Text for nag_sym_eig
      ! NAG fl90, Release 4. NAG Copyright 2000.

      ! .. Use Statements ..
      USE nag_examples_io, ONLY : nag_std_in, nag_std_out
      USE nag_write_mat, ONLY : nag_write_gen_mat
      USE nag_sym_eig, ONLY : nag_key_cmplx, nag_sym_tridiag_reduc, &
       nag_sym_tridiag_eig_all
      ! .. Implicit None Statement ..
      IMPLICIT NONE
      ! .. Intrinsic Functions ..
      INTRINSIC KIND
      ! .. Parameters ..
      INTEGER, PARAMETER :: wp = KIND(1.0D0)
      ! .. Local Scalars ..
      INTEGER :: i, n
      CHARACTER (1) :: uplo
      ! .. Local Arrays ..
      REAL (wp), ALLOCATABLE :: d(:), e(:)
      COMPLEX (wp), ALLOCATABLE :: a(:,:)
      ! .. Executable Statements ..
      WRITE (nag_std_out,*) 'Example Program Results for nag_sym_eig_ex03'

      READ (nag_std_in,*)          ! Skip heading in data file
      READ (nag_std_in,*) uplo
      READ (nag_std_in,*) n

      ALLOCATE (a(n,n),d(n),e(n-1)) ! Allocate storage

      SELECT CASE (uplo)
      CASE ('L','l')
        READ (nag_std_in,*) (a(i,:i),i=1,n)
      CASE ('U','u')
        READ (nag_std_in,*) (a(i,i:),i=1,n)
      END SELECT

      ! Reduce A to real symmetric tridiagonal form

      CALL nag_sym_tridiag_reduc(uplo,a,d,e,q_on_a=.TRUE.)

      WRITE (nag_std_out,*)
      WRITE (nag_std_out,*) 'Diagonal of the tridiagonal matrix T'
      WRITE (nag_std_out,'(12X,5(F6.3:,10X))') d
      WRITE (nag_std_out,*) 'Super-diagonal of the tridiagonal matrix T'
      WRITE (nag_std_out,'(12X,5(F6.3:,10X))') e

      ! Compute all the eigenvalues and eigenvectors of A

      CALL nag_sym_tridiag_eig_all(nag_key_cmplx,d,e,z_tridiag=.FALSE.,z=a)

      WRITE (nag_std_out,*)
      WRITE (nag_std_out,*) 'Eigenvalues'
      WRITE (nag_std_out,'(12X,5(F6.3:,10X))') d
      WRITE (nag_std_out,*)

      CALL nag_write_gen_mat(a,format='(F6.3)',title='Eigenvectors')

      DEALLOCATE (a,d,e)           ! Deallocate storage

    END PROGRAM nag_sym_eig_ex03