Program f08wafe

!     F08WAF Example Program Text

!     Mark 25 Release. NAG Copyright 2014.

!     .. Use Statements ..
      Use nag_library, Only: dggev, nag_wp, x02amf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nb = 64, nin = 5, nout = 6
!     .. Local Scalars ..
      Complex (Kind=nag_wp)            :: eig
      Real (Kind=nag_wp)               :: small
      Integer                          :: i, info, j, lda, ldb, ldvr, lwork, n
      Logical                          :: pair
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: a(:,:), alphai(:), alphar(:),        &
                                          b(:,:), beta(:), vr(:,:), work(:)
      Real (Kind=nag_wp)               :: dummy(1,1)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: abs, cmplx, max, nint
!     .. Executable Statements ..
      Write (nout,*) 'F08WAF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      ldb = n
      ldvr = n
      Allocate (a(lda,n),alphai(n),alphar(n),b(ldb,n),beta(n),vr(ldvr,n))

!     Use routine workspace query to get optimal workspace.
      lwork = -1
!     The NAG name equivalent of dggev is f08waf
      Call dggev('No left vectors','Vectors (right)',n,a,lda,b,ldb,alphar, &
        alphai,beta,dummy,1,vr,ldvr,dummy,lwork,info)

!     Make sure that there is enough workspace for blocksize nb.
      lwork = max((nb+7)*n,nint(dummy(1,1)))
      Allocate (work(lwork))

!     Read in the matrices A and B

      Read (nin,*)(a(i,1:n),i=1,n)
      Read (nin,*)(b(i,1:n),i=1,n)

!     Solve the generalized eigenvalue problem

!     The NAG name equivalent of dggev is f08waf
      Call dggev('No left vectors','Vectors (right)',n,a,lda,b,ldb,alphar, &
        alphai,beta,dummy,1,vr,ldvr,work,lwork,info)

      If (info>0) Then
        Write (nout,*)
        Write (nout,99999) 'Failure in DGGEV. INFO =', info
      Else
        small = x02amf()
        pair = .False.
        Do j = 1, n
          Write (nout,*)
          If ((abs(alphar(j))+abs(alphai(j)))*small>=abs(beta(j))) Then
            Write (nout,99998) 'Eigenvalue(', j, ')', &
              ' is numerically infinite or undetermined', 'ALPHAR(', j, &
              ') = ', alphar(j), ', ALPHAI(', j, ') = ', alphai(j), ', BETA(', &
              j, ') = ', beta(j)
          Else
            If (alphai(j)==0.0E0_nag_wp) Then
              Write (nout,99997) 'Eigenvalue(', j, ') = ', alphar(j)/beta(j)
            Else
              eig = cmplx(alphar(j),alphai(j),kind=nag_wp)/ &
                cmplx(beta(j),kind=nag_wp)
              Write (nout,99996) 'Eigenvalue(', j, ') = ', eig
            End If
          End If
          Write (nout,*)
          Write (nout,99995) 'Eigenvector(', j, ')'
          If (alphai(j)==0.0E0_nag_wp) Then
            Write (nout,99994)(vr(i,j),i=1,n)
          Else
            If (pair) Then
              Write (nout,99993)(vr(i,j-1),-vr(i,j),i=1,n)
            Else
              Write (nout,99993)(vr(i,j),vr(i,j+1),i=1,n)
            End If
            pair = .Not. pair
          End If
        End Do

      End If

99999 Format (1X,A,I4)
99998 Format (1X,A,I2,2A/1X,2(A,I2,A,1P,E11.4,3X),A,I2,A,1P,E11.4)
99997 Format (1X,A,I2,A,1P,E11.4)
99996 Format (1X,A,I2,A,'(',1P,E11.4,',',1P,E11.4,')')
99995 Format (1X,A,I2,A)
99994 Format (1X,1P,E11.4)
99993 Format (1X,'(',1P,E11.4,',',1P,E11.4,')')
    End Program f08wafe