Program f08gcfe

!     F08GCF Example Program Text

!     Mark 26 Release. NAG Copyright 2016.

!     .. Use Statements ..
      Use nag_library, Only: blas_damax_val, dspevd, nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Real (Kind=nag_wp), Parameter    :: zero = 0.0E0_nag_wp
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: r
      Integer                          :: i, ifail, info, j, k, ldz, liwork,   &
                                          lwork, n
      Character (1)                    :: job, uplo
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: ap(:), w(:), work(:), z(:,:)
      Integer, Allocatable             :: iwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F08GCF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      ldz = n
      liwork = 5*n + 3
      lwork = n*n + 6*n + 1
      Allocate (ap(n*(n+1)/2),w(n),work(lwork),z(ldz,n),iwork(liwork))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)((ap(i+j*(j-1)/2),j=i,n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)((ap(i+(2*n-j)*(j-1)/2),j=1,i),i=1,n)
      End If

      Read (nin,*) job

!     Calculate all the eigenvalues and eigenvectors of A
!     The NAG name equivalent of dspevd is f08gcf
      Call dspevd(job,uplo,n,ap,w,z,ldz,work,lwork,iwork,liwork,info)

      Write (nout,*)
      If (info>0) Then
        Write (nout,*) 'Failure to converge.'
      Else

!       Print eigenvalues and eigenvectors

        Write (nout,*) 'Eigenvalues'
        Write (nout,99999) w(1:n)
        Write (nout,*)
        Flush (nout)

!       Normalize the eigenvectors: largest element positive
        Do i = 1, n
          Call blas_damax_val(n,z(1,i),1,k,r)
          If (z(k,i)<zero) Then
            z(1:n,i) = -z(1:n,i)
          End If
        End Do

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call x04caf('General',' ',n,n,z,ldz,'Eigenvectors',ifail)

      End If

99999 Format (3X,(8F8.4))
    End Program f08gcfe