Program f08gffe

!     F08GFF Example Program Text

!     Mark 26 Release. NAG Copyright 2016.

!     .. Use Statements ..
      Use nag_library, Only: blas_damax_val, dopgtr, dsptrd, dsteqr, nag_wp,   &
                             x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Real (Kind=nag_wp), Parameter    :: zero = 0.0E0_nag_wp
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: r
      Integer                          :: i, ifail, info, j, k, ldq, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: ap(:), d(:), e(:), q(:,:), tau(:),   &
                                          work(:)
!     .. Executable Statements ..
      Write (nout,*) 'F08GFF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      ldq = n
      Allocate (ap(n*(n+1)/2),d(n),e(n),q(ldq,n),tau(n),work(2*n-2))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)((ap(i+j*(j-1)/2),j=i,n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)((ap(i+(2*n-j)*(j-1)/2),j=1,i),i=1,n)
      End If

!     Reduce A to tridiagonal form T = (Q**T)*A*Q
!     The NAG name equivalent of dsptrd is f08gef
      Call dsptrd(uplo,n,ap,d,e,tau,info)

!     Form Q explicitly, storing the result in Q
!     The NAG name equivalent of dopgtr is f08gff
      Call dopgtr(uplo,n,ap,tau,q,ldq,work,info)

!     Calculate all the eigenvalues and eigenvectors of A
!     The NAG name equivalent of dsteqr is f08jef
      Call dsteqr('V',n,d,e,q,ldq,work,info)

      Write (nout,*)
      If (info>0) Then
        Write (nout,*) 'Failure to converge.'
      Else

!       Print eigenvalues and eigenvectors

        Write (nout,*) 'Eigenvalues'
        Write (nout,99999) d(1:n)
        Write (nout,*)
        Flush (nout)

!       Normalize the eigenvectors: largest element positive
        Do i = 1, n
          Call blas_damax_val(n,q(1,i),1,k,r)
          If (q(k,i)<zero) Then
            q(1:n,i) = -q(1:n,i)
          End If
        End Do

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call x04caf('General',' ',n,n,q,ldq,'Eigenvectors',ifail)

      End If

99999 Format (3X,(8F8.4))
    End Program f08gffe